Merciful 2/Merciful - Disc 2.iso/software/b/backmanv1.3g+keufile.lha/Install/Install BackMan

Text File | 1995-04-26 | 4KB | 216 lines

;**
;**  $VER: Install 1.0 (15.04.95)
;**  Copyright © 1995 Sandro Tolaini
;**

;**
;**  English strings
;**

(if (= @language "english")
    (
        (set #bad-kick "This program requires kickstart v37 (2.04) or higher.")
        (set #bad-mui "You must install MUI 2.3 or higher before installing BackMan!")
        (set #inst-bin "Installing BackMan binaries")
        (set #inst-cat "Installing catalog files")
        (set #inst-doc "Installing documentation")
        (set #inst-xpk "Installing XPK libraries:\n")
        (set #choose-dest "Choose where BackMan's drawer will be created")
        (set #choose-doclang "Choose the documentation's language")
        (set #choose-catlang "Choose which catalogs you want to install")
        (set #ask-doc "Do you want to install the documentation?")
        (set #welcome "Welcome registered user! Thanks for your support!")
        (set #language "English") ;Default docs language
        (set #langnum 0)
    )
)

;**
;**  Italian strings
;**

(if (= @language "italiano")
    (
        (set #bad-kick "Questo programma richiede il kickstart v37 (2.04) o superiore.")
        (set #bad-mui "Devi installare MUI 2.3 o superiore prima di installare BackMan!")
        (set #inst-bin "Installazione dei programmi in corso")
        (set #inst-cat "Installazione dei cataloghi in corso")
        (set #inst-doc "Installazione della documentazione in corso")
        (set #inst-xpk "Installazione delle librerie XPK in corso:\n")
        (set #choose-dest "Scegli dove verrà creato il cassetto di BackMan")
        (set #choose-doclang "Scegli la lingua della documentazione")
        (set #choose-catlang "Scegli quali cataloghi vuoi installare")
        (set #ask-doc "Vuoi installare la documentazione?")
        (set #welcome "Benvenuto utente registrato! Grazie per il tuo supporto!")
        (set #language "Italiano") ;Default docs language
        (set #langnum 1)
    )
)

;**
;**  Startup checks
;**

(if (< (/ (getversion) 65536) 37)
    (abort #bad-kick)
)

(if (< (/ (getversion "LIBS:muimaster.library") 65536) 10)
    (abort #bad-mui)
)

;**
;**  Installing BackMan!
;**

(welcome)

(set @default-dest
    (askdir
        (prompt #choose-dest)
        (help @askdir-help)
        (default @default-dest)
    )
)

(set @default-dest (tackon @default-dest "BackMan"))

;**
;**  Copy binaries
;**

(complete 0)

(if (exists "Bin/BackMan.Key")
    (
        (message #welcome)
    )
)

(copyfiles
    (prompt #inst-bin)
    (source "Bin")
    (dest @default-dest)
    (infos)
    (all)
)

;**
;**  Copy XPK libraries
;**

(complete 25)

(copylib
    (prompt #inst-xpk "xpkmaster.library")
    (help @copylib-help)
    (source "Libs/xpkmaster.library")
    (dest "LIBS:")
    (optional nofail force)
    (confirm)
)

(foreach "Libs/Compressors" "xpk????.library"
    (copylib
        (prompt #inst-xpk @each-name)
        (help @copylib-help)
        (source (tackon "Libs/Compressors" @each-name))
        (dest "LIBS:Compressors")
        (optional nofail force)
        (confirm)
    )
)

;**
;**  Copy catalogs
;**

(complete 50)

(if (exists "LOCALE:" (noreq))
    (
        (if (> @user-level 0)
            (
                (set #bitmask
                    (askoptions
                        (prompt #choose-catlang)
                        (help @askoptions-help)
                        (choices "Italiano")
                    )
                )
            )
            (
                (set #bitmask -1)
            )
        )

        (set n 0)
        (while (set #language (select n "Italiano" ""))
            (
                (if (IN #bitmask n)
                    (
                        (copyfiles
                            (prompt #inst-cat)
                            (source (tackon "Catalogs" #language))
                            (dest (tackon "LOCALE:Catalogs" #language))
                            (all)
                        )
                    )
                )
                (set n (+ n 1))
            )
        )
    )
)

;**
;**  Copy docs
;**

(complete 75)

(if (OR (< @user-level 2) (askbool (prompt #ask-doc) (help @askbool-help)))
    (
        (if (> @user-level 0)
            (
                (set #language
                    (select
                        (askchoice
                            (prompt #choose-doclang)
                            (help @askchoice-help)
                            (choices "English" "Italiano")
                            (default #langnum)
                        )
                        "English" "Italiano"
                    )
                )
            )
        )

        (copyfiles
            (prompt #inst-doc)
            (source (tackon "Docs" #language))
            (dest @default-dest)
            (all)
        )

        (copyfiles
            (prompt #inst-doc)
            (source "Docs")
            (dest @default-dest)
            (all)
            (files)
            (infos)
        )
    )
)

;**
;**  Installation complete!
;**

(complete 100)

(exit)